#!/usr/bin/perl -w

use strict; 

my $target = "/target"; 
my @datadirs = qw(var home); 
my $defaultmirror = 'http://mirrors.kernel.org/debian'; 
my $defaultlocaltime = "EST/EDT";

my @packages = qw(
    less wget w3m vim libncurses5-dev make gcc mbr bzip2 mdadm ssh finger
);
my @failpackages = qw(
    lilo
);

BEGIN { 
    print <<END;

raidthingy.pl version 8, released 2007-07-18.

Welcome to this installer thingy. Using the procedure described at
http://juerd.nl/debianraid, this tool installs a Debian GNU/Linux system on
RAID 1 or 5.

Before using this tool, you must evaluate it (by reading its source code) and
determine if it is suitable for your intended application. The author accepts
no responsibility. 

In other words: your computer may explode, and it is not my fault.

If you have read the source code and really want to continue, type this line
followed by enter:

    Zie de maan schijnt door de bomen.

Otherwise, just hit enter to abort.

END

    while (print("Sinterklaas: "), defined($_ = <>)) { 
        /^$/ and warn("Aborted.\n")  and exit;
        /^Zie de maan schijnt door de bomen\.?$/i and last;
        warn "That's not the correct line.\n"; 
    } 
}

sub SYSTEM { 
    my @copy = @_; 
    s/\bmissing\d\b/missing/ for @copy;  # XXX - ugly!
    TRY: {
        printf "Executing: %s\n", map "[$_]", @copy;
        system @copy;
        if ($?) { 
            warn "Command failed, \$? == $?\n";
            print "What do you want to do? ('abort', 'retry', 'ignore')";
            for (;;) {
                print 'Now what? ';
                my $i = <>; 
                $i =~ /^abort$/ and die "Aborted.\n"; 
                $i =~ /^retry$/ and redo TRY;
                $i =~ /^ignore$/ and last;
            }
        }
    }
}

SANITY_CHECKS: {
    # XXX - need many more!
    -d $target and die "$target exists, aborted.\n";

    SYSTEM "modprobe md";
    SYSTEM "modprobe raid1";
    SYSTEM "modprobe raid5";

    if (not -e "/dev/md0") {
        SYSTEM "mknod /dev/md$_ b 9 $_" for 0..3;
    }
}

print <<END;

Which drives do you wish to use? Enter 1 or 2 drives for RAID 1 and more for
RAID 5. Do note that this tool only functions correctly if the drives are
identical, at least 40 GB, and empty. (80 GB or larger is recommended.)

If you enter only one drive, a 2 drive array with the second drive "missing"
will be assumed. You can add it later.

The drives you enter must be valid devices in /dev. If you want to use sda and
sdb, enter "sda sdb". To use hda, hdc, hde and hdg, enter "hda hdc hde hdg".
END

my @drives;

while (not @drives) {
    print 'Drives: ';
    @drives = map "/dev/$_", split ' ', <>;
    for (my @copy = @drives) {
        if (not -w) {
            warn "$0: $_: $!\n";
            @drives = ();
        }
    }
}
my $raid = @drives < 3 ? 1 : 5;

print <<END;

Pick a debian mirror near you from http://www.debian.org/mirror/list, and enter
the full URI here. Make sure you include "http://" or "ftp://" and a trailing
"/debian". If you enter nothing, $defaultmirror will be used.
END

print 'Mirror: ';

my $mirror = <>;
chomp $mirror;
$mirror ||= $defaultmirror;

print <<END;

What is your localtime? Pick one from /usr/share/zoneinfo/

Examples: "CET", "Europe/Amsterdam".

DO NOT GUESS, but enter an actual known file!

The default is $defaultlocaltime, so if you want that, just press enter.
END

print 'Timezone: ';

my $localtime = <>;
chomp $localtime;
$localtime ||= $defaultlocaltime;

print <<END;

We'll be bootstrapping using etch, but if you want, we can upgrade to sid
("unstable") after that. Do you want a bleading edge system?

Enter "yes" or "no".
END

my $dist;

while (not $dist) {
    print 'Sid? ';
    my $i = <>;
    $i =~ /^yes$/ and $dist = "sid";
    $i =~ /^no$/  and $dist = "etch";
}

print <<END;

Think of a cute name for this machine (the hostname). Some people like to use a
fully qualified name here, others exclude the domain part. Debian suggests you
use only the hostname, so "foo" instead of "foo.bar". There is no default for
this option.
END

my $hostname;

while (not $hostname) {
    print 'Hostname: ';
    $hostname = <>;
    chomp $hostname;
}

my $rootsize = $raid == 1
    ? 25
    : int(25/@drives) + 1;

my $fdisk = <<"END";
new primary 1 default +64M
new primary 2 default +1G
new extended 3 default default
new logical default +${rootsize}G
new logical default default
activate 1
type 1 FD
type 2 FD
type 5 FD
type 6 FD
write
END

$fdisk =~ s/\bdefault\b/\0/g;
$fdisk =~ s/([a-z])\w+/$1/g;

# Stupid fdisk won't work with fast pipes...

#$fdisk = join '', map "$_\\r", split ' ', $fdisk;
#$fdisk =~ tr/\0//d;
#SYSTEM "echo -ne '$fdisk' | fdisk $_" for @drives;


for (@drives) {
    print "Executing slowly: [fdisk $_]\n";
    open my $fdiskpipe, "|fdisk $_" or die $!;
    my $o = select $fdiskpipe;
    $|++;
    select $o;
    for (split ' ', $fdisk) {
        select(undef, undef, undef, 0.3);
        my $c = $_;
        $c =~ s/\0//g;
        print "$_\n";
        print $fdiskpipe "$_\n";
    }
    close $fdiskpipe;
    $? and die "fdisk failed, \$? == $?.\n"   
}


{
    my @drives = @drives == 1 ? (@drives, 'missing') : @drives;

    my $ndrives = @drives;

    SYSTEM "mdadm --create /dev/md0 -e 0.90 -n $ndrives -l 1 ". "@{[ map $_ . 1, @drives ]}";

    SYSTEM "mdadm --create /dev/md1 -e 0.90 -n $ndrives -l $raid @{[ map $_ . 2, @drives ]}";
    SYSTEM "mdadm --create /dev/md2 -e 0.90 -n $ndrives -l $raid @{[ map $_ . 5, @drives ]}";
    SYSTEM "mdadm --create /dev/md3 -e 0.90 -n $ndrives -l $raid @{[ map $_ . 6, @drives ]}";
}

SYSTEM "mkfs.ext3 /dev/md0";
SYSTEM "mkswap    /dev/md1";
SYSTEM "mkfs.ext3 /dev/md2";
SYSTEM "mkfs.ext3 /dev/md3 -O dir_index";

SYSTEM "mkdir $target";
SYSTEM "mount /dev/md2 $target";

SYSTEM "mkdir $target/boot";
SYSTEM "mount /dev/md0 $target/boot";

SYSTEM "mkdir $target/data";
SYSTEM "mount /dev/md3 $target/data";

for (@datadirs) {
    SYSTEM "mkdir $target/data/$_";
    SYSTEM "mkdir $target/$_";
    SYSTEM "mount --bind $target/data/$_ $target/$_";
}

SYSTEM "debootstrap etch $target $mirror";

SYSTEM "cd $target/etc; rm -f hostname resolv.conf localtime";

SYSTEM "cp /etc/resolv.conf $target/etc/resolv.conf";
SYSTEM "ln -s /usr/share/zoneinfo/$localtime $target/etc/localtime";
SYSTEM "echo $hostname > $target/etc/hostname";
SYSTEM "perl -i.default -pe's/FSCKFIX=no/FSCKFIX=yes/' $target/etc/default/rcS";

my $fstab = <<END;
/dev/md0   /boot ext3 defaults 0 1
/dev/md1   none  swap swap
/dev/md2   /     ext3 defaults,errors=remount-ro 0 1
/dev/md3   /data ext3 defaults,errors=remount-ro 0 1
proc       /proc proc
END

$fstab .= "/data/$_ /$_ bind bind\n" for @datadirs;
$fstab =~ s/\n/\\n/g;

SYSTEM "echo -ne '$fstab' > $target/etc/fstab";

my $sources = <<END;
deb $mirror $dist main contrib non-free
deb-src $mirror $dist main contrib non-free
deb http://security.debian.org/ etch/updates main
END

$sources =~ s/\n/\\n/g;

SYSTEM "echo -ne '$sources' > $target/etc/apt/sources.list";

my $lilo = <<END;
boot=/dev/md0
root=/dev/md2
compact
lba32
read-only

image=/vmlinuz
initrd=/initrd.img
label=Linux
END

$lilo =~ s/\n/\\n/g;

SYSTEM "echo -ne '$lilo' > $target/etc/lilo.conf";

my $interfaces = <<END;
auto lo
iface lo inet loopback

auto eth0
iface eth0 inet dhcp
# or:
# iface eth0 inet static
#     address 1.2.3.4
#     netmask 255.255.255.0
#     gateway 1.2.3.1
END

$interfaces =~ s/\n/\\n/g;

SYSTEM "echo -ne '$interfaces' > $target/etc/network/interfaces";

print "--> chrooting to $target <--\n";
chroot $target or die $!;
$ENV{HOSTNAME} = $hostname;

SYSTEM "mount -t proc none /proc";
SYSTEM "shadowconfig on";

chdir '/dev';
SYSTEM "MAKEDEV generic";

if ($dist eq 'sid') {
	SYSTEM "apt-get update";
	SYSTEM "apt-get -y --force-yes install dpkg apt";
	SYSTEM "apt-get -y --allow-unauthenticated install gnupg debian-keyring";
	SYSTEM "gpg --list-keys";  # init ~/.gnupg
	SYSTEM "echo keyring /usr/share/keyrings/debian-keyring.gpg >> ~/.gnupg/gpg.conf";
}
SYSTEM "apt-get update";  # Yes, a second time.

SYSTEM "apt-get -y dist-upgrade";
SYSTEM "apt-get -y install @packages";

print "Executing carelessly: [apt-get -y install @failpackages]\n";
system "apt-get -y install @failpackages";  # lilo may fail at this point



SYSTEM "install-mbr $_" for @drives;


print <<END;

Almost done... Set a root password:
END

SYSTEM "passwd";

my $kvtries = 0;
my $kv;
{
    $kv = join "", grep /latest stable/, `finger \@kernel.org | sed -ne 2p`;
    sleep 1, redo if !$kv and $kvtries++ < 5;
}
$kv &&= "\n\n$kv\n";

print <<END;

Here ends the automated part of the installation. In order to be able to boot
your new system, you will need to install a kernel. You're on your own for
that. This is step 15 at http://juerd.nl/debianraid.$kv

Don't forget to compile in RAID 1 and 5 support!! 

After you've installed your new kernel as /boot/vmlinuz, run lilo.

If you need to configure your network for something other than DHCP, edit
/etc/network/interfaces.

When you're all done, exit the chrooted shell and reboot. Good luck!

END

chdir '/usr/src';
SYSTEM "bash";

print "\nYou're no longer chrooted now.\n";

# Remove the following line before use
#BEGIN { die "\nThat was lovely, but you should really read the source first.\n" }