project(gladtex)
cmake_minimum_required(VERSION 2.8.5)

find_package(ZLIB REQUIRED)
find_package(PNG REQUIRED)
find_package(GIF)

if(GIF_FOUND)
    include_directories(${GIF_INCLUDE_DIR})
    add_definitions(-DGIF)
endif()

include_directories(${ZLIB_INCLUDE_DIRS} ${PNG_INCLUDE_DIRS})

set(eqn2img_SRCS
    eqn2img.c
)

if(WIN32)
    set(eqn2img_SRCS ${eqn2img_SRCS} getopt.c)
endif()

if(MSVC)
    add_definitions(-D_CRT_SECURE_NO_WARNINGS -wd4996)
endif()

add_executable(eqn2img ${eqn2img_SRCS})
target_link_libraries(eqn2img ${ZLIB_LIBRARIES} ${PNG_LIBRARIES})
if(GIF_FOUND)
    target_link_libraries(eqn2img ${GIF_LIBRARIES})
endif(GIF_FOUND)

find_program(POD2MAN pod2man)
if(POD2MAN)
    message(STATUS "found pod2man for generation of documentation: ${POD2MAN}")
    add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/gladtex.1
                       COMMAND ${POD2MAN} ARGS -c \"User Commands\" -r \"gladtex 1.3\" ${CMAKE_SOURCE_DIR}/gladtex.pod > ${CMAKE_BINARY_DIR}/gladtex.1)
    add_custom_target(gladtex.1_custom ALL DEPENDS ${CMAKE_BINARY_DIR}/gladtex.1)
endif()

install(TARGETS eqn2img RUNTIME DESTINATION bin
                        LIBRARY DESTINATION lib
                        ARCHIVE DESTINATION lib)
install(PROGRAMS gladtex DESTINATION bin)
install(FILES eqn2img.1 DESTINATION share/man/man1)
if(POD2MAN)
    install(FILES ${CMAKE_BINARY_DIR}/gladtex.1 DESTINATION share/man/man1)
endif()
